# Maintainer: Christian Schendel <doppelhelix@gmail.com>

pkgname=aaxtomp3
pkgver=1.4.1
pkgrel=3
pkgdesc="Convert Audible's .aax filetype to MP3, FLAC, M4A, or OPUS"
url='https://github.com/doppelhelix/AAXtoMP3'
arch=('any')
license=(
    WTFPL
)
makedepends=(
    git
)
optdepends=(
    'jq: only if --use-audible-cli-data is set or converting an .aaxc file'
    'mediainfo: adds additional media tags'
    'libmp4v2'
)
source=("$pkgname::git+$url.git#tag=v$pkgver?signed")
validpgpkeys=(
    '47D15FC0F6AD8433CD06B4DF5874D2437CD5BBB3' # Christian Schendel <doppelhelix@gmail.com>
)
sha256sums=('f027200c7fdce6d7e128c7441967290e6f6a48e732074be510ac948fa20f8b11')

package() {
    depends+=(
        bash
        bc
        ffmpeg
        glib2
        gtk4
        lame
        python
        python-gobject
    )
    cd $pkgname
    install -Dm0755 -t "$pkgdir/usr/bin/" AAXtoMP3 AAXtoMP3_gui interactiveAAXtoMP3
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
}

# vim: set ft=sh ts=4 sw=4 et: