# Maintainer: Christian Schendel <doppelhelix@gmail.com>

pkgname=aaxtomp3
pkgver=1.4.1
pkgrel=4
pkgdesc="Convert Audible's .aax filetype to MP3, FLAC, M4A, or OPUS"
url='https://codeberg.org/doppelhelix/AAXtoMP3'
arch=(
    any
)
license=(
    WTFPL
)
makedepends=(
    git
)
optdepends=(
    'jq: only if --use-audible-cli-data is set or converting an .aaxc file'
    'mediainfo: adds additional media tags'
    'libmp4v2'
)
source=("${pkgname}-${pkgver}::git+${url}.git#tag=v${pkgver}?signed")
validpgpkeys=(
    '47D15FC0F6AD8433CD06B4DF5874D2437CD5BBB3' # Christian Schendel <doppelhelix@gmail.com>
)
b2sums=('0820e6649459b95ad839a666a7a1c15773dd1642dc15ba044532d28835056a5f16a313eeadd86fe23881695d90a80c06506566e9c423775300e14f54db2953c6')

package() {
    depends+=(
        bash
        bc
        ffmpeg
        glib2
        gtk4
        lame
        python
        python-gobject
    )
    cd "${pkgname}-${pkgver}"
    install -Dm0755 -t "${pkgdir}/usr/bin/" \
        AAXtoMP3 AAXtoMP3_gui interactiveAAXtoMP3
    install -Dm0644 -t "${pkgdir}/usr/share/doc/${pkgname}/" \
        README.md
    install -Dm0644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" \
        LICENSE
}

# vim: set ft=sh ts=4 sw=4 et: