# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: ayrton @linux.com
# Developer: pheiduck @forum.manjaro.org

pkgname=arch-zsh-config-git
_pkgname=manjaro-zsh-config-git
pkgver=r101.7838ead
pkgrel=1
pkgdesc="Zsh configuration from manjaro forked for all the cool kids"
arch=(any)
url="https://github.com/doppelhelix/${pkgname%-git}"
license=('MIT')
conflicts=('grml-zsh-config')
makedepends=(
    'git'
)
provides=("${pkgname%-git}")
conflicts=(
    "${pkgname%-git}"
    "$_pkgname"
    "${_pkgname%-git}")
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')
backup=(root/.zshrc)

pkgver() {
    cd "$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
    depends+=(
        pkgfile
        ttf-nerd-fonts-symbols
        ttf-nerd-fonts-symbols-mono
        zsh
        zsh-autosuggestions
        zsh-completions
        zsh-history-substring-search
        zsh-syntax-highlighting
        zsh-theme-powerlevel10k
    )
    cd "$srcdir"
    install -Dm0644 -t "$pkgdir/usr/share/licenses/${pkgname}" "$srcdir/$pkgname/LICENSE"
    install -Dm0644 -t "$pkgdir/etc/skel" "$srcdir/$pkgname/.zshrc"
    install -Dm0644 -t "$pkgdir/usr/share/zsh" "$srcdir/$pkgname/manjaro-zsh-config"
    install -Dm0644 -t "$pkgdir/usr/share/zsh" "$srcdir/$pkgname/manjaro-zsh-prompt"
    install -Dm0644 -t "$pkgdir/usr/share/zsh" "$srcdir/$pkgname/zsh-maia-prompt"
    install -Dm0644 -t "$pkgdir/usr/share/zsh" "$srcdir/$pkgname/p10k.zsh"
    install -Dm0644 -t "$pkgdir/usr/share/zsh" "$srcdir/$pkgname/p10k-portable.zsh"
    install -Dm0644 -t "$pkgdir/usr/share/zsh/functions" "$srcdir/$pkgname/command-not-found.zsh"
    install -Dm0640 "$srcdir/$pkgname/rootzshrc" "$pkgdir/root/.zshrc"
    chmod 700 "$pkgdir/root"
    mkdir -p "$pkgdir/usr/share/zsh/scripts"
    cp -r "$srcdir/$pkgname/base16-shell" "$pkgdir/usr/share/zsh/scripts"
    chmod a+x "$pkgdir/usr/share/zsh/scripts/base16-shell/"*
}

# vim: set ft=sh ts=4 sw=4 et: