# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: A. Klitzing <aklitzing@gmail.com>

pkgname=ausweisapp2
pkgver=2.3.2
pkgrel=3
pkgdesc="A software application that you install on your computer to use your national identity card or your electronic residence permit for online identification"
arch=('i686' 'x86_64' 'aarch64')
license=('EUPL-1.2')
url="https://www.ausweisapp.bund.de/"
depends=(
    gcc-libs
    glibc
    hicolor-icon-theme
    http-parser
    openssl
    pcsclite
    qt6-base
    qt6-declarative
    qt6-svg
    qt6-websockets
    qt6-scxml
    systemd-libs
)
makedepends=(
    cmake
    ninja
    pkgconf
    python
    qt6-shadertools
    qt6-tools
    vulkan-headers
)
optdepends=(
    'ccid: Smart Card Interface'
    'acsccid: ACS CCID smart card readers'
    'pcsc-cyberjack: Driver for Reiner SCT cyberjack Cardreaders'
)
source=("https://github.com/Governikus/AusweisApp2/releases/download/${pkgver}/AusweisApp-${pkgver}.tar.gz"{,.asc})
validpgpkeys=('699BF3055B0A49224EFDE7C72D7479A531451088')
b2sums=('aff32283161f479d682cf8f54148baafb8bd684c573cf0394069e29c1871dc7ed1aac1ddb8a7135262e4807dea66bb2870c50311aec0b42576ebed51b16d37fd'
        'SKIP')

prepare() {
    cd "AusweisApp-$pkgver"
}

build() {
    local cmake_options=(
        -G Ninja
        -B build
        -D CMAKE_BUILD_TYPE=MinSizeRel
        -D CMAKE_INSTALL_PREFIX=/usr
        -W no-dev
        -S "${srcdir}/AusweisApp-${pkgver}"
    )
    cmake "${cmake_options[@]}"
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
    install -Dm644 "${srcdir}/AusweisApp-${pkgver}/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
}

# vim: set ft=sh ts=4 sw=4 et: