# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: giskard <rtgiskard@gmail.com>

pkgname=bibata-modern-classic-cursor
pkgver=1.0.0
pkgrel=2
pkgdesc='Bibata Cursor Theme (Modern Classic only), including hyprcursor and Xcursor'
arch=('any')
url="https://github.com/rtgiskard/bibata_cursor"
license=(
    GPL-3.0-or-later
)
conflicts=(
    bibata-cursor-theme
)
makedepends=(
    git
    librsvg
    python
    xorg-xcursorgen
)
options+=(
    !strip
)
source=("$pkgname-$pkgver::git+$url.git#tag=v$pkgver")
b2sums=('15cde380e3da5815a0a2def4c03e11214eb6c8386d9c9b9b956da8001bfe051834ec89f8e705e99d88df3a53d5810a9de41bdaba1fe61b66826bc8b78aeb793b')

build() {
    cd "$pkgname-$pkgver"
    ./src/cursor_utils.py --hypr --x11 --x11-symlink all --theme Bibata-Modern-Classic --out-dir out
}

package() {
    cd "$pkgname-$pkgver"
    install -d "$pkgdir/usr/share/icons"
    cp -r out/Bibata-* "$pkgdir/usr/share/icons/"
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" readme.adoc
}

# vim: set ft=sh ts=4 sw=4 et: