# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: goetzc
# Contributor: Kim Scarborough <sluggo@unknown.nu>

pkgname=cantata-qt6
pkgdesc="Qt6 graphical client for Music Player Daemon (MPD), nullobsi fork"
pkgver=3.4.0
pkgrel=1
url="https://github.com/nullobsi/cantata"
arch=(x86_64 i686 aarch64 armv7h)
license=(
    'GPL-3.0-or-later'
)
makedepends=(
    cmake
    git
    qt6-tools
    vulkan-headers
)
depends=(
    avahi
    bash
    ffmpeg
    gcc-libs
    glibc
    hicolor-icon-theme
    karchive
    kitemviews
    libcddb
    libcdio-paranoia
    libebur128
    libmtp
    libmusicbrainz5
    media-player-info
    mpg123
    perl
    perl-uri
    qt6-base
    qt6-multimedia
    qt6-svg
    systemd-libs
    taglib
    #taglib-extras
    udisks2
    zlib
)
optdepends=(
    'mpd: Playback'
)
provides=(cantata)

source=("${pkgname%-qt6}-$pkgver::git+$url.git#tag=v${pkgver}?signed")
sha256sums=('0d178d7bb46ee720abc4de57d80786809d6b74391624a4d5c8c71793953b0f9e')
validpgpkeys=('EAAC1F701A83BED288D064DC933A1F44222C2634')  # Citlali del Rey <me@nullob.si>
build() {
    CXXFLAGS+=" -Wno-error=unused-result -Wno-error=deprecated-declarations -Wno-unused-result"
    local cmake_options=(
        -B build
        -S "${pkgname%-qt6}-$pkgver"
        -D CMAKE_BUILD_TYPE=None
        -D CMAKE_INSTALL_PREFIX=/usr
        -D CMAKE_INSTALL_LIBEXECDIR=/usr/lib
        -D BUNDLED_FONTAWESOME=ON
        -D QT_DIR=/usr/lib/cmake/Qt6
        -W no-dev
    )
    cmake "${cmake_options[@]}"
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build

    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-qt6}" "$srcdir/${pkgname%-qt6}-$pkgver/INSTALL"
    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-qt6}" "$srcdir/${pkgname%-qt6}-$pkgver/README"
    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-qt6}" "$srcdir/${pkgname%-qt6}-$pkgver/README.md"
    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-qt6}" "$srcdir/${pkgname%-qt6}-$pkgver/TODO"
}

# vim: set ft=sh ts=4 sw=4 et: