# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: goetzc
# Contributor: Kim Scarborough <sluggo@unknown.nu>

pkgname=cantata-qt6
pkgdesc="Qt6 graphical client for Music Player Daemon (MPD), nullobsi fork"
pkgver=3.3.1
pkgrel=6
url="https://github.com/nullobsi/cantata"
arch=(x86_64 i686 aarch64 armv7h)
license=(
    'GPL-3.0-or-later'
)
makedepends=(
    cmake
    git
    qt6-tools
    vulkan-headers
)
depends=(
    avahi
    bash
    ffmpeg
    gcc-libs
    glibc
    hicolor-icon-theme
    kitemviews
    libcddb
    libcdio-paranoia
    libebur128
    libmtp
    libmusicbrainz5
    media-player-info
    mpg123
    perl
    perl-uri
    qt6-base
    qt6-multimedia
    qt6-svg
    systemd-libs
    taglib
    #taglib-extras
    udisks2
    zlib
)
optdepends=(
    'mpd: Playback'
)
provides=(cantata)

source=("${pkgname%-qt6}-$pkgver::git+$url.git#tag=v${pkgver}?signed")
sha256sums=('c282fd13610e6521696a9caaa5772952b16a9ff2a64192fdc379d9074ebdb96c')
validpgpkeys=('EAAC1F701A83BED288D064DC933A1F44222C2634')  # Citlali del Rey <me@nullob.si>
build() {
    cmake \
        -B build \
        -S "${pkgname%-qt6}-$pkgver" -Wno-dev \
        -DBUNDLED_FONTAWESOME=ON \
        -DQT_DIR=/usr/lib/cmake/Qt6 \
        -DCMAKE_BUILD_TYPE=None \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBEXECDIR=/usr/bin

    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build

    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-qt6}" "$srcdir/${pkgname%-qt6}-$pkgver/INSTALL"
    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-qt6}" "$srcdir/${pkgname%-qt6}-$pkgver/README"
    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-qt6}" "$srcdir/${pkgname%-qt6}-$pkgver/README.md"
    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-qt6}" "$srcdir/${pkgname%-qt6}-$pkgver/TODO"
}

# vim: set ft=sh ts=4 sw=4 et: