pkgbuild: cosmic-ext-tweaks-0.2.0-1: new upstream release

PKGBUILD

@@ -0,0 +1,53 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: Mark Wagie <mark dot wagie at proton dot me>
+
+pkgname=cosmic-ext-tweaks
+pkgver=0.2.0
+pkgrel=1
+pkgdesc="A tweaking tool for the COSMIC desktop."
+arch=(
+    x86_64
+)
+url="https://github.com/cosmic-utils/tweaks"
+license=(
+    GPL-3.0-or-later)
+depends=(
+    gcc-libs
+    glibc
+    hicolor-icon-theme
+    libxkbcommon
+    openssl
+)
+makedepends=(
+    cargo
+    clang
+    git
+    just
+    mold
+)
+source=(
+    "${pkgname}-${pkgver}::git+${url}.git#tag=${pkgver}"
+)
+
+b2sums=('509da0a1fc2f403dcb763d381e519598c785f9ecf6fdb63e1c7b5592ca07843d5e6d4fec48e6363316206ad36a36097abfe8841e7c351822b57cea95879d6cee')
+
+prepare() {
+    cd "${pkgname}-${pkgver}"
+    export RUSTUP_TOOLCHAIN=stable
+    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+    cd "${pkgname}-${pkgver}"
+    export RUSTUP_TOOLCHAIN=stable
+    export CC=clang
+    RUSTFLAGS+=" -C link-arg=-fuse-ld=mold"
+    just build-release --frozen
+}
+
+package() {
+    cd "${pkgname}-${pkgver}"
+    just rootdir="${pkgdir}" install
+}
+
+# vim: set ft=sh ts=4 sw=4 et: