Initial commit

PKGBUILD

@@ -0,0 +1,53 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: JakobDev<jakobdev at gmx dot de>
+pkgname=cubiomes-viewer
+pkgver=4.1.2
+pkgrel=2
+pkgdesc="An efficient graphical Minecraft seed finder and map viewer"
+arch=('x86_64')
+url="https://github.com/Cubitect/cubiomes-viewer"
+license=(
+    GPL-3.0-or-later
+)
+depends=(
+    glibc
+    gcc-libs
+    hicolor-icon-theme
+    qt5-base
+)
+makedepends=(
+    git
+    qt5-tools
+)
+source=(
+    "$pkgname-$pkgver::git+$url.git#tag=$pkgver"
+    "git+https://github.com/Cubitect/cubiomes.git"
+)
+b2sums=('aa909e803c3f2817c46fb71f3494180d70639468b40a1cb9a627f995a0e5811374c497aa410c374863466a551a97da2340ef02a06e6e79df4d735287a6daf4cd'
+        'SKIP')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  git submodule init
+  git config submodule.libs/cubiomes.url "$srcdir/cubiomes"
+  git -c protocol.file.allow=always submodule update
+}
+
+
+build() {
+    cd "$pkgname-$pkgver"
+    mkdir -p build
+    cd build
+    qmake CONFIG+=without_network ..
+    make
+}
+
+package() {
+    cd "$pkgname-$pkgver"
+    install -Dm0755 -t "$pkgdir/usr/bin" "build/cubiomes-viewer"
+    install -Dm0644 -t "$pkgdir/usr/share/applications" "etc/com.github.cubitect.cubiomes-viewer.desktop"
+    install -Dm0644 -t "$pkgdir/usr/share/metainfo" "etc/com.github.cubitect.cubiomes-viewer.metainfo.xml"
+    install -Dm0644 -t "$pkgdir/usr/share/icons/hicolor/scalable/apps/com.github.cubitect.cubiomes-viewer.svg" "etc/icon.svg"
+}
+
+# vim: set ft=sh ts=4 sw=4 et: