# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Gavin Lyons <glyons66@hotmail.com>
# https://github.com/gavinlyonsrepo/cylon
pkgname=cylon
pkgver=6.4
pkgrel=6
pkgdesc="Updates, Maintenance, backup and system checks in a menu driven TUI written in Bash"
arch=('any')
url="https://github.com/gavinlyonsrepo/cylon"
license=(
    GPL-3.0-or-later
)
makedepends=(
    git
)
optdepends=(
    'auracle-git: AUR helper'
    'trizen: AUR helper'
    'lostfiles: For finding lost files'
    'arch-audit: collect CVE data'
    'rmlint: Finds lint and other unwanted files'
    'bleachbit: used for system clean'
    'gnu-netcat: used for checking network'
    'openbsd-netcat: used for checking network'
    'libnotify: desktop notifications'
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=$pkgver"
    "io.github.gavinlyonsrepo.cylon.metainfo.xml"
    "cylonicon.svg"
    "desktop.patch"
)
b2sums=('2b72dfbdf595d60fe98c8f96d1dc8d18c95be845073aab1c85b4752993771f061e99067d0d93192e1b40fa90fd5115767991cd08dccdfde21ebb5dcd10ef2949'
        '0b2aa78c8c982539f1b855cc0f646a79ace5c1c37989d17f91e6a57d8406d83b8cdb68f8637a97649bd590e08c55a2a4199b8ae2cf42e3f63099198c3782a69e'
        'c9c7ae71eec0eb410e1ba06fe762dd718506e23d1531a7e6b83fba8c804ee88ed7c0d9cf994c2819e1fc58c175ee1feb3361481d61bca064952a53e32540d5b2'
        '2bebd78db39b75d8f11b87d2466d2bc26633183a54a600ac54863373cd68495005fec59b71b88db1bf59f459af8c9287890c0299d492110ba15ce0f0d38a682a')

prepare() {
    patch -d $pkgname-$pkgver -Np1 -i ../desktop.patch
}

package() {
    depends+=(
        bash
        dialog
        expac
        pacman-contrib
    )
    cd "${pkgname}-${pkgver}"
    install -Dm0755 main/Cylon.sh "$pkgdir"/usr/bin/"${pkgname}"

    install -d "$pkgdir"/usr/lib/cylon/modules
    install -Dm0644  modules/*_module "$pkgdir"/usr/lib/cylon/modules
    
    install -d "$pkgdir"/usr/share/doc/"${pkgname}"
    install -Dm0644 README.md "$pkgdir/usr/share/doc/${pkgname}/Readme.md"
    install -Dm0644 documentation/help/*.md "$pkgdir/usr/share/doc/${pkgname}/"
    
    install -Dm0644 documentation/help/cylon.7 \
        "$pkgdir/usr/share/man/man7/cylon.7"
    
    install -Dm0644 desktop/cylon.desktop \
        "$pkgdir/usr/share/applications/io.github.gavinlyonsrepo.cylon.desktop"
    install -Dm0644 ../cylonicon.svg \
        "$pkgdir/usr/share/icons/hicolor/scalable/apps/io.github.gavinlyonsrepo.cylon.svg"
    install -Dm644 ../io.github.gavinlyonsrepo.cylon.metainfo.xml \
        "${pkgdir}/usr/share/metainfo/io.github.gavinlyonsrepo.cylon.metainfo.xml"
}

# vim: set ft=sh ts=4 sw=4 et: