# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Gavin Lyons <glyons66@hotmail.com>
# https://github.com/gavinlyonsrepo/cylon
pkgname=cylon
pkgver=6.4
pkgrel=4
pkgdesc="Updates, Maintenance, backup and system checks in a menu driven TUI written in Bash"
arch=('any')
url="https://github.com/gavinlyonsrepo/cylon"
license=(
    GPL-3.0-or-later
)
makedepends=(
    git
)
optdepends=(
    'auracle-git: AUR helper'
    'trizen: AUR helper'
    'lostfiles: For finding lost files'
    'arch-audit: collect CVE data'
    'rmlint: Finds lint and other unwanted'
    'bleachbit: used for system clean'
    'gnu-netcat: used for checking network'
    'openbsd-netcat: used for checking network'
    'libnotify: desktop notifications'
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=$pkgver"
    "io.github.gavinlyonsrepo.cylon.metainfo.xml"
    "cylonicon.svg"
)
b2sums=('2b72dfbdf595d60fe98c8f96d1dc8d18c95be845073aab1c85b4752993771f061e99067d0d93192e1b40fa90fd5115767991cd08dccdfde21ebb5dcd10ef2949'
        'f166b3671cdad778a4eaea556349a1d7a9ea1c26eb9768d9a1e098de9492487518ff87a05a11fefa1f7a6460629002a570a1aa02ca878531203919781484ae25'
        'c9c7ae71eec0eb410e1ba06fe762dd718506e23d1531a7e6b83fba8c804ee88ed7c0d9cf994c2819e1fc58c175ee1feb3361481d61bca064952a53e32540d5b2')

package() {
    depends+=(
        bash
        dialog
        expac
        pacman-contrib
    )
    cd "${pkgname}-${pkgver}"
    install -Dm0755 main/Cylon.sh "$pkgdir"/usr/bin/"${pkgname}"

    install -d "$pkgdir"/usr/lib/cylon/modules
    install -Dm0644  modules/*_module "$pkgdir"/usr/lib/cylon/modules
    
    install -d "$pkgdir"/usr/share/doc/"${pkgname}"
    install -Dm0644 README.md "$pkgdir/usr/share/doc/${pkgname}/Readme.md"
    install -Dm0644 documentation/help/*.md "$pkgdir/usr/share/doc/${pkgname}/"
    
    install -Dm0644 documentation/help/cylon.7 \
        "$pkgdir/usr/share/man/man7/cylon.7"
    
    install -Dm0644 desktop/cylon.desktop \
        "$pkgdir/usr/share/applications/cylon.desktop"
    install -Dm0644 ../cylonicon.svg \
        "$pkgdir/usr/share/icons/hicolor/scalable/apps/cylonicon.svg"
    install -Dm644 ../io.github.gavinlyonsrepo.cylon.metainfo.xml \
        "${pkgdir}/usr/share/metainfo/io.github.gavinlyonsrepo.cylon.metainfo.xml"
}

# vim: set ft=sh ts=4 sw=4 et: