# Maintainer: Christian Schendel <doppelhelix@gmail.com>

pkgname=enpass-bin
pkgver=6.11.12.1953
pkgrel=4
pkgdesc='A multiplatform password manager'
arch=(x86_64)
url='http://enpass.io/'
license=(
    'LicenseRef-terms-of-use'
)

optdepends=(
    'libxdg-basedir: Open links in the default browser.'
    'libqtxdg: Open links in the default browser (Qt implementation)'
)

provides=("${pkgname%-bin}")
conflicts=("${pkgname%-bin}")

install='enpass-bin.install'
source=(
    "https://apt.enpass.io/pool/main/e/enpass/${pkgname%-bin}_${pkgver}_amd64.deb"
    "terms-of-use.md"
    "com.enpass.enpass.metainfo.xml"
)
b2sums=('ece8aae433b3797614d82ae07d5b7322e48c43cf0d5e6db7aff1e48f67ac220c2fb066b6a61f311f613a56480c9bf4323c13effa3e112f11eab1e10511d944fd'
        'b257d6ba4689f80e5e79a8ec075acefd7c35338abc2f0b9dda19dd1c81145a69dbff1095cb6d8d68ae5d38aeb5332dff370bf26ae7eb6f21c3f0125fcf9d278d'
        '497fe441c83ecbb9d21bd33f4f51103328d29818a12ac9748008312583ee445c7a2eca5e2f377372ca452c51f3712425364ca681470eb838c62eb69efe39c1e5')

# Disable strip as otherwise the browser extension will not work
options=(
    '!strip'
)

package() {
    depends+=(
        curl
        dbus
        fontconfig
        freetype2
        glib2
        glibc
        gtk3
        hicolor-icon-theme
        libcups
        libglvnd
        libice
        libpulse
        libsm
        libx11
        libxcb
        libxkbcommon
        libxkbcommon-x11
        libxss
        lsof
        pango
        util-linux-libs
        xcb-util-image
        xcb-util-keysyms
        xcb-util-renderutil
        xcb-util-wm
        xz
        zlib
    )

    # Extract data
    tar xfz "${srcdir}/data.tar.gz" -C "${pkgdir}" --no-same-owner

    # Remove unnecessary files which are included in the .deb
    # find "${pkgdir}" -name '*~' -delete

    # Update permissions to match the default system ones
    chmod -R go-w "${pkgdir}/opt/"
    chmod 755 "${pkgdir}/opt/"
    find "${pkgdir}/usr/" -type d -exec chmod 755 {} \;
    find "${pkgdir}/usr/" -type f -exec chmod 644 {} \;

    # Symlink "runenpass.sh" to "/usr/bin" so it is accessible via cli
    mkdir -p "${pkgdir}/usr/bin"
    ln -s '/opt/enpass/Enpass' "${pkgdir}/usr/bin/enpass"

    install -Dm644 "${srcdir}/terms-of-use.md" \
        "${pkgdir}/usr/share/licenses/${pkgname}/terms-of-use.md"

    install -Dm644 "${srcdir}/com.enpass.enpass.metainfo.xml" \
        "${pkgdir}/usr/share/metainfo/com.enpass.enpass.metainfo.xml"
}

# vim: set ft=sh ts=4 sw=4 et: