# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Khorne <khorne@khorne.me>

pkgname=escribe-suite-bin
pkgver=2_SP68
pkgrel=1
pkgdesc="Evolv eScribe Suite - DNA Management Suite and Ecigstats - INTL Version"
arch=('x86_64')
url="https://forum.evolvapor.com/topic/69197-linux-escribe-suite-beta-thread/"
license=(
    LicenseRef-custom
)
makedepends=(
    unzip
)
optdepends=(
    'hardinfo: For system information utility'
)
source=("https://downloads.evolvapor.com/SetupEScribe${pkgver//./_}_INT.run"
        "escribe-suite-bin.sh"
        "escribe-suite-bin.desktop"
        "ecigstats.desktop")
b2sums=('cc6cbbd8a8a8be361fc7afa154e36ee76410356b48a51d71057ebfc21f954ecca830884b47fe5cd7e3f98038f0c1c0319d64718d975827ea425a7b811a96a464'
        '2151c44c156dff69c9ade3884ca061bfac58ec3b6c886d5ca73ad7317b65034bc3c220d8b916454a6487085457c786e3a95f5971110432ccabd6959497cd8a47'
        '01fe26868c534d6b749243c1fc6d30ef0693bf516235efcefa342f36114eecb6db87364fd63c5641a4b031d4f01c2dc88a14d6e92bd4213ad70328388c331277'
        '457e5c7be94b76038967a04cf586cdbbb66331fdcb9dac841d2b1f1773374e1dec6e664f1e6a48732df81622c21e0f16c7cd63c25d3f74732d66abf043975d59')
prepare() {
	chmod +x "SetupEScribe${pkgver//./_}_INT.run"
	./"SetupEScribe${pkgver//./_}_INT.run" --target . --noexec
	cd common/data
	unzip -o escribe-suite.zip -d main/
        unzip -o ecigstats.zip -d components/
        rm -f ./*.zip
}

package() {
    depends=(
        bash
        gtk2
        gtk-sharp-2
        mono
    )
    mkdir -p "${pkgdir}/opt/${pkgname}"
    cp -r common/data/* "${pkgdir}/opt/${pkgname}"

    # Update permissions to match the default system ones
    find "${pkgdir}/opt/" -type d -exec chmod 755 {} \;
    find "${pkgdir}/opt/" -type f -exec chmod 644 {} \;

    install -Dm0644 "common/data/License.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    install -Dm0644 "${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
    install -Dm0644 "ecigstats.desktop" "${pkgdir}/usr/share/applications/ecigstats.desktop"
    install -Dm0755 "${pkgname}.sh" "${pkgdir}/usr/bin/escribe-suite"
}

# vim: set ft=sh ts=4 sw=4 et: