# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Khorne <khorne@khorne.me>

pkgname=escribe-suite-bin
pkgver=2_SP71
pkgrel=3
pkgdesc="Evolv eScribe Suite - DNA Management Suite and Ecigstats - INTL Version"
arch=('x86_64')
url="https://forum.evolvapor.com/topic/69197-linux-escribe-suite-beta-thread/"
license=(
    LicenseRef-custom
)

depends=(
    bash
    gtk3
    #gtk-sharp-3
    mono
)
makedepends=(
    unzip
)
optdepends=(
    'hardinfo: For system information utility'
)
source=(
    "https://downloads.evolvapor.com/SetupEScribe${pkgver//./_}_INT.run"
    "escribe-suite-bin.sh"
    "escribe-suite-bin.desktop"
    "ecigstats.desktop"
    "icons.tar.gz"
)
b2sums=('c382bfaabb7f998814090217fd8e7a2cb11b5df712f7a1b82029752e9474e46ea6ea91370c35b2e6c9ba5607e91018ffb586cacaf5fd5cc350e6b67709d277ca'
        '2151c44c156dff69c9ade3884ca061bfac58ec3b6c886d5ca73ad7317b65034bc3c220d8b916454a6487085457c786e3a95f5971110432ccabd6959497cd8a47'
        'e1da9fab6386571ae2a3300acd3439df2c7dea712786155f58f8917b669d8378d7e13b664716cfb6e299c197091bffbe643b5cd0bb41bf73f11eec425fe2362d'
        'c4331fac8b73a99b87bcab4a8f9cdb4d506402887919778c661b2003c402eb0e58e5b6fc43282983678968d920bd096e6d4fbd8f130890819724f340dadfb1cd'
        '3ff2f6322e9e291028a2c7b3ffab5b4de9984ff8d1a2c0f69f7e9eea60e5bfecf785726fcbdd25632d6c90042560b4c7fc686139e257829e9f91256562f77c29')
prepare() {
	chmod +x "SetupEScribe${pkgver//./_}_INT.run"
	./"SetupEScribe${pkgver//./_}_INT.run" --target . --noexec
	cd common/data
	unzip -o escribe-suite.zip -d main/
        unzip -o ecigstats.zip -d components/
        rm -f ./*.zip
}

package() {
    mkdir -p "${pkgdir}/opt/${pkgname}"
    cp -r common/data/* "${pkgdir}/opt/${pkgname}"

    # Update permissions to match the default system ones
    find "${pkgdir}/opt/" -type d -exec chmod 755 {} \;
    find "${pkgdir}/opt/" -type f -exec chmod 644 {} \;

    install -Dm0644 "common/data/License.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    install -Dm0644 "${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
    install -Dm0644 "ecigstats.desktop" "${pkgdir}/usr/share/applications/ecigstats.desktop"
    install -Dm0755 "${pkgname}.sh" "${pkgdir}/usr/bin/escribe-suite"
    mv -f icons "${pkgdir}/usr/share"
}

# vim: set ft=sh ts=4 sw=4 et: