# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Huynh Thien Khiem <my_github_name 2000 at gmail dot com>
pkgname=euphonica
pkgver=0.96.3_beta
pkgrel=1
pkgdesc="Libadwaita MPD client with visualiser, wikis and synced lyrics"
arch=(
    x86_64
)
url="https://github.com/htkhiem/euphonica"
license=(
    GPL-3.0-or-later
)
depends=(
    cairo
    dbus
    dconf
    gcc-libs
    gdk-pixbuf2
    glib2
    glibc
    graphene
    gtk4
    hicolor-icon-theme
    libadwaita
    libpipewire
    openssl
    pango
    sqlite
    xdg-desktop-portal-gtk
)
makedepends=(
    git
    meson
    cargo
    clang
)
options=(!lto)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v${pkgver//_/-}"
    "3fb892b20144e0fb3a705e77e3de9b64480b5086.patch"
)
b2sums=('bcf2c916b74021af3b943f181aefeeb0d2cde0c5b6b80a8a556f727b00cec82082a883290b5651090ea4ed8a6374c1ad067ff5af3f88b063baf05358aba96415'
        'SKIP')

prepare() {
    export RUSTUP_TOOLCHAIN=stable
    cd "$pkgname-$pkgver"
    patch -Np1 -i ../3fb892b20144e0fb3a705e77e3de9b64480b5086.patch
}

build() {
    export RUSTUP_TOOLCHAIN=stable
    arch-meson "$pkgname-$pkgver" build
    meson compile -C build
}

check() {
    meson test -C build --print-errorlogs
}

package() {
    meson install -C build --no-rebuild --destdir "$pkgdir"
}

# vim: set ft=sh ts=4 sw=4 et: