# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Huynh Thien Khiem <my_github_name 2000 at gmail dot com>
pkgname=euphonica
pkgver=0.97.0_beta
pkgrel=1
pkgdesc="Libadwaita MPD client with visualiser, wikis and synced lyrics"
arch=(
    x86_64
)
url="https://github.com/htkhiem/euphonica"
license=(
    GPL-3.0-or-later
)
depends=(
    cairo
    #dbus
    dconf
    gcc-libs
    gdk-pixbuf2
    glib2
    glibc
    graphene
    gtk4
    hicolor-icon-theme
    libadwaita
    libpipewire
    libsecret
    org.freedesktop.secrets
    openssl
    pango
    sqlite
    #xdg-desktop-portal-gtk
)
makedepends=(
    git
    meson
    cargo
    clang
)
options=(!lto)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v${pkgver//_/-}"
)
b2sums=('e8b6cc00051f9abacb42a0cd4d184a2723bec24cccf5a4bb589fd618e6fb1d80c862474e54483d5c4e8541c7b04d2e0a72bebd91ab7ec249e504dd6a28ed2a67')

build() {
    export RUSTUP_TOOLCHAIN=stable
    arch-meson "$pkgname-$pkgver" build
    meson compile -C build
}

check() {
    meson test -C build --print-errorlogs
}

package() {
    meson install -C build --no-rebuild --destdir "$pkgdir"
}

# vim: set ft=sh ts=4 sw=4 et: