# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Huynh Thien Khiem <my_github_name 2000 at gmail dot com>
pkgname=euphonica
pkgver=0.97.2_beta
pkgrel=1
pkgdesc="Libadwaita MPD client with visualiser, wikis and synced lyrics"
arch=(
    x86_64
)
url="https://github.com/htkhiem/euphonica"
license=(
    GPL-3.0-or-later
)
depends=(
    cairo
    #dbus
    dconf
    gcc-libs
    gdk-pixbuf2
    glib2
    glibc
    graphene
    gtk4
    hicolor-icon-theme
    libadwaita
    libpipewire
    libsecret
    org.freedesktop.secrets
    openssl
    pango
    sqlite
    #xdg-desktop-portal-gtk
)
makedepends=(
    git
    meson
    cargo
    clang
)
options=(!lto)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v${pkgver//_/-}"
    "io.github.htkhiem.Euphonica.desktop.in.patch"
)
b2sums=('698091cf2f734c119f9f27ad73ecd914fce304a0be2f8317e14a95d42470c063ecdf5652e9ee8696bde14e04b9444b1890d9cc7d7600281344b6e4ea34861b8b'
        '0708a600fa0df62dccc58de07c0ced52260d37a0e4f2bbdfeb4f4234081ed164eb2534b502065a0522afcaf82d8432032aec4e2786ae47d7bcea595c8fa69ef3')

prepare() {
    patch -d $pkgname-$pkgver \
        -Np1 -i ../io.github.htkhiem.Euphonica.desktop.in.patch
}

build() {
    export RUSTUP_TOOLCHAIN=stable
    arch-meson "$pkgname-$pkgver" build
    meson compile -C build
}

check() {
    meson test -C build --print-errorlogs
}

package() {
    meson install -C build --no-rebuild --destdir "$pkgdir"
}

# vim: set ft=sh ts=4 sw=4 et: