# Maintainer: Christian Schendel <doppelhelix at gmail dot com>
pkgname=gnome-shell-extension-applications-overview-tooltip
pkgdesc="Shows a tooltip over applications icons on applications overview"
pkgver=24
pkgrel=1
url="https://github.com/RaphaelRochet/applications-overview-tooltip"
arch=(any)
license=(LicenseRef-unknown-license-LICENSE.md)
depends=(
    dconf
    'gnome-shell>=1:46'
)
makedepends=(
    git
    glib2
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
    'LICENSE.md'
)
b2sums=('8cddd4f4868b92337794ea73b50f5642c901acef4df12260fa4ca41d09da4bada4fa689628a39e95b7746a5378687dc5ace1183d76d2070a1b7a7ef768d3a689'
        'd876adfdc5c20fa4e8f56adc4e070adb3598d8d5820da063b1ade0f0c2ca959150d4bc973e628482f168d33916d482d5534a4910b6ded1f836b0e09ad213c8cb')

package() {
    cd "$pkgname-$pkgver"
    local uuid
    local schema
    uuid=$(grep -Po '(?<="uuid": ")[^"]*' metadata.json)
    schema=$(grep -Po '(?<="settings-schema": ")[^"]*' metadata.json).gschema.xml
    local destdir="$pkgdir"/usr/share/gnome-shell/extensions/"$uuid"

    install -dm0755 "$destdir"
    find . -regextype posix-egrep -regex ".*\.(js|json|xml|css)$" \
        -exec install -Dm 644 {} "$destdir"/{} \;
    rm -rf "${destdir}"/schemas

    install -Dm0644 -t "$pkgdir"/usr/share/glib-2.0/schemas/ schemas/"$schema"
    install -Dm0644 -t "$pkgdir"/usr/share/doc/"$pkgname"/ README.md
    install -Dm0644 -t "$pkgdir"/usr/share/doc/"$pkgname"/ screenshot.png
    install -Dm0644 -t "$pkgdir"/usr/share/licenses/"$pkgname"/ ../LICENSE.md

    find . -regextype posix-egrep -regex ".*\.(mo)$" -exec install -Dm 644 {} "$pkgdir"/usr/share/{} \;
}

# vim: set ft=sh ts=4 sw=4 et: