# Maintainer: Christian Schendel <doppelhelix@gmail.com>
pkgname=gnome-shell-extension-arch-update
pkgdesc="Update indicator for ArchLinux and Gnome-Shell"
pkgver=64
pkgrel=2
url="https://github.com/RaphaelRochet/arch-update"
arch=('any')
license=(
    GPL-3.0-or-later
)
makedepends=(
    git
)
depends=(
    dconf
    fakeroot
    'gnome-shell>=1.46'
    pacman-contrib
)
optdepends=(
    gnome-terminal
)
source=("$pkgname-$pkgver::git+$url.git#tag=v$pkgver")
sha256sums=('6b07945587fa4ffa7baaea77f43d15c819dc20bf8caeb299b376689f7323ea5a')

package() {
    cd "$(dirname "$(find . -name 'metadata.json' -print -quit)")"
    local uuid
    uuid=$(grep -Po '(?<="uuid": ")[^"]*' metadata.json)
    local schema
    schema=$(grep -Po '(?<="settings-schema": ")[^"]*' metadata.json).gschema.xml
    local destdir="$pkgdir"/usr/share/gnome-shell/extensions/"$uuid"

    install -dm0755 "$destdir"
    find . -regextype posix-egrep -regex ".*\.(js|json|css|xml|svg)$" \
        -exec install -Dm 644 {} "$destdir"/{} \;
    rm -rf "$destdir/schemas"

    install -Dm0644 -t "$pkgdir/usr/share/glib-2.0/schemas" "schemas/$schema"
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
    cp -r --no-preserve=ownership,mode locale "$pkgdir"/usr/share
}

# vim: set ft=sh ts=4 sw=4 et: