# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# OriginalMaintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=gnome-shell-extension-blur-my-shell
pkgdesc="Extension that adds a blur look to different parts of the GNOME Shell"
pkgver=70
pkgrel=1
arch=('any')
url="https://github.com/aunetx/blur-my-shell"
license=(
    GPL-3.0-or-later
)
depends=(
    dconf
    'gnome-shell>=1:46'
)
makedepends=(
    git
)
source=("$pkgname-$pkgver::git+$url.git#tag=v$pkgver")
b2sums=('e943397543159ee2029436a4796351c3a5a1fab7e8055d738a1c715485462878cabe99f65a98067c0e621027cf3acc389c0b14975e15af6a8f891e4ea0ef53c2')

build() {
    cd "$pkgname-$pkgver"
    make build
}

package() {
    cd "$pkgname-$pkgver"
    local uuid
    uuid=$(grep -Po '(?<="uuid": ")[^"]*' metadata.json)
    schema=$(grep -Po '(?<="settings-schema": ")[^"]*' metadata.json).gschema.xml
    local destdir="$pkgdir/usr/share/gnome-shell/extensions/$uuid"

    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" README.md

    cd build
    install -dm0755 "$destdir"
    bsdtar xvf "${uuid}".shell-extension.zip

    find . -regextype posix-egrep -regex ".*\.(css|glsl|js|json|svg|ui)$" -exec\
        install -Dm0644 {} "$destdir"/{} \;

    cp -r locale "$pkgdir"/usr/share/
    install -Dm0644 -t "$pkgdir"/usr/share/glib-2.0/schemas/ schemas/"$schema"
}

# vim: set ts=4 sw=4 et: