# Maintainer: Christian Schendel (doppelhelix@gmail.com)

pkgname=gnome-shell-extension-nightthemeswitcher
pkgver=79
pkgrel=2
pkgdesc="Automatically toggle your light and dark themes variants"
arch=('any')
url="https://gitlab.com/rmnvgr/nightthemeswitcher-gnome-shell-extension"
license=(
    GPL-2.0-or-later
    GPL-3.0-or-later
    'MIT OR LGPL-2.0-or-later'
    CC-BY-NC-SA-4.0
)

depends=(
    dconf
    'gnome-shell>=1:48'
)
makedepends=(
    git
    eslint
    meson
)
source=("$pkgname-$pkgver::git+$url.git#tag=$pkgver")
b2sums=('e11ad9e2a338df661a8ce896d31be84755e8aaba8f970269dd427d1acd5a5fe566dedaea7f02861324c43bb9198f18ddf6672abd0eb39de5d7ebe1aa9c03ef13')

build() {
    cd "$pkgname-$pkgver"
    arch-meson build
    meson compile -C build
}

package() {
    cd "$pkgname-$pkgver"
    local uuid
    uuid=$(grep -Po '(?<=UUID = \x27)[^\x27]*' meson.build)
    local schema
    schema=$(grep -Po '(?<=DNS = \x27)[^\x27]*' meson.build).gschema.xml
    local destdir="$pkgdir/usr/share/gnome-shell/extensions/$uuid"

    meson install -C build --destdir "$pkgdir"

    install -Dm0644 -t "$pkgdir/usr/share/glib-2.0/schemas" \
        "$destdir/schemas/$schema"
    rm -rf "$destdir/schemas"

    cp -r "$pkgdir/usr/share/gnome-shell/extensions/${uuid}/locale" \
        "$pkgdir/usr/share"
    rm -rf "$destdir/locale"

    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" \
        README.md CONTRIBUTING.md CHANGELOG.md
    cp -r res "$pkgdir/usr/share/doc/$pkgname"

    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.md
}

# vim: set ft=sh ts=4 sw=4 et: