Initial commit

2025-09-04 21:52:54 +02:00 · 2025-09-04 21:52:54 +02:00 · 305cf9b127
commit 305cf9b127
12 changed files with 1215 additions and 0 deletions
--- a/101
+++ b/101
@ -0,0 +1,101 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: Christian Heusel <christian@heusel.eu>
+# Contributor: Knut Ahlers <knut at ahlers dot me>
+# Contributor: Det <nimetonmaili g-mail>
+# Contributor: t3ddy, Lex Rivera aka x-demon, ruario, Abdullah
+
+# Check for new Linux releases in: http://googlechromereleases.blogspot.com/search/label/Stable%20updates
+# or use: $ curl -sSf https://dl.google.com/linux/chrome/deb/dists/stable/main/binary-amd64/Packages | grep -A1 "Package: google-chrome-stable" | awk '/Version/{print $2}' | cut -d '-' -f1
+
+pkgname=google-chrome-bin
+pkgver=140.0.7339.80
+pkgrel=1
+pkgdesc="The popular web browser by Google (Stable Channel)"
+arch=(x86_64)
+url="https://www.google.com/chrome"
+license=(
+    LicenseRef-eula_text.html
+)
+options=(
+    '!emptydirs'
+    '!strip'
+)
+install=$pkgname.install
+_channel=stable
+source=(
+    "https://dl.google.com/linux/chrome/deb/pool/main/g/google-chrome-${_channel}/google-chrome-${_channel}_${pkgver}-1_amd64.deb"
+    'eula_text.html'
+    "google-chrome-$_channel.sh")
+b2sums=('3e89ac5712dfa7424f4ef76d157968a8ee2e883222786b37c29c3cc689426446565dda745923082d62894435d1b70f9e987852026c2fcd38e91f1c085e412abb'
+        '9127cd1be47ff4cf0d0ee7e84d4c86dc0d5a22470c10ede103f78a9b441a391fc769c560cb505637567f9d6c499baa20f19506a1b2fbbe807f84f6cbcbe9e93e'
+        '2e6ec319eb6ea37c3066183e1fed7e5a4c781dc3de3aef8c8eefebcb0a95fce79cbb109c3c723c73e6d7a4c84e949f0924a8d1ae2646dddfb6668d8d8322d2c6')
+
+package() {
+    depends+=(
+        alsa-lib
+        at-spi2-core
+        bash
+        cairo
+        dbus
+        expat
+        gcc-libs
+        glib2
+        glibc
+        gtk3
+        hicolor-icon-theme
+        libcups
+        libx11
+        libxcb
+        libxkbcommon
+        libxcomposite
+        libxdamage
+        libxfixes
+        libxext
+        libxrandr
+        libxss
+        libxtst
+        mesa
+        nspr
+        nss
+        pango
+        qt6-base
+        systemd-libs
+        ttf-liberation
+        xdg-utils
+)
+    optdepends+=(
+        'kdialog: for file dialogs in KDE'
+        'org.freedesktop.secrets: for storing passwords keyring'
+        'pipewire: WebRTC desktop sharing under Wayland'
+)
+    bsdtar -xf data.tar.xz -C "$pkgdir/"
+
+    # Launcher
+    install -m755 google-chrome-$_channel.sh \
+        "$pkgdir"/usr/bin/google-chrome-$_channel
+
+    # Icons
+    for i in 16x16 24x24 32x32 48x48 64x64 128x128 256x256; do
+        install -Dm644 "$pkgdir"/opt/google/chrome/product_logo_${i/x*/}.png \
+            "$pkgdir"/usr/share/icons/hicolor/$i/apps/google-chrome.png
+    done
+
+    # License
+    install -Dm644 eula_text.html \
+        "$pkgdir"/usr/share/licenses/$pkgname/eula_text.html
+    install -Dm644 "$pkgdir"/opt/google/chrome/WidevineCdm/LICENSE \
+        "$pkgdir"/usr/share/licenses/google-chrome-$_channel/WidevineCdm-LICENSE.txt
+
+    # Fix the Chrome desktop entry
+    sed -i \
+        -e "/Exec=/i\StartupWMClass=Google-chrome" \
+        -e "s/x-scheme-handler\/ftp;\?//g" \
+        "$pkgdir"/usr/share/applications/google-chrome.desktop
+
+    # Remove the Debian Cron job, duplicate product logos and menu directory
+    rm -r \
+        "$pkgdir"/etc/cron.daily/ \
+        "$pkgdir"/opt/google/chrome/cron/ \
+        "$pkgdir"/opt/google/chrome/product_logo_*.{png,xpm} \
+        "$pkgdir"/usr/share/menu/
+}