grimblast/PKGBUILD

# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Elias Werberich <elias at werberich dot de>
# Contributor: Struan Robertson <struanrobertson@protonmail.com>

pkgname=grimblast
pkgver=2025.12.16
_commit="41dbcac8183bb1b3a4ade0d8276b2f2df6ae4690" # 2025-12-16
pkgrel=1
pkgdesc="A helper for screenshots within Hyprland."
arch=(any)
url="https://github.com/hyprwm/contrib"
license=(
    MIT
)
makedepends=(
    scdoc
    git
)
source=(
    "${pkgname}-${pkgver}::git+${url}.git#commit=${_commit}"
)
b2sums=('1132bc4a9e7cef4fd43e72be7b3a5e5a20cd89abf47bbe2c575aee6281c2095f51b60d166a433aa46dcac6a3212140828cac42fa7a5e93c9dd095617d219004d')

build() {
    cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"
    scdoc < grimblast.1.scd > grimblast.1
}

package() {
    depends+=(
        bash
        grim
        hyprland
        hyprpicker
        jq
        slurp
    )
    cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"

    install -Dm0644 ${pkgname}.1 "$pkgdir/usr/share/man/man1/${pkgname}.1"
    install -Dm0755 ${pkgname} "$pkgdir/usr/bin/${pkgname}"
    install -Dm0644 "$srcdir/${pkgname}-${pkgver}/LICENSE" \
        "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}

# vim: set ft=sh ts=4 sw=4 et: