Initial commit

PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: Elias Werberich <elias at werberich dot de>
+# Contributor: Struan Robertson <struanrobertson@protonmail.com>
+
+pkgname=grimblast
+pkgver=2025.07.22
+_commit="6839b23345b71db17cd408373de4f5605bf589b8" # 2025-07-22
+pkgrel=1
+pkgdesc="A helper for screenshots within Hyprland."
+arch=(any)
+url="https://github.com/hyprwm/contrib"
+license=(
+    MIT
+)
+
+makedepends=(
+    scdoc
+    git
+)
+source=(
+    "$pkgname-$pkgver::git+$url.git#commit=$_commit"
+)
+b2sums=('40645fb87b2a83e25022bd99464b3e9c256c53f4a784a1e27f6b5f10af8dbb1bc6a5194e2011ea6c3c7aafa87c2232cd0e51de0448fa73665a81e3457b6db14d')
+
+build() {
+    cd "$srcdir/$pkgname-$pkgver/$pkgname"
+    scdoc < grimblast.1.scd > grimblast.1
+}
+
+package() {
+    depends+=(
+        bash
+        grim
+        hyprland
+        jq
+        slurp
+    )
+    cd "$srcdir/$pkgname-$pkgver/$pkgname"
+
+    install -Dm0644 $pkgname.1 "$pkgdir/usr/share/man/man1/$pkgname.1"
+    install -Dm0755 $pkgname "$pkgdir/usr/bin/$pkgname"
+    install -Dm0644 "$srcdir/$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim: set ft=sh ts=4 sw=4 et: