# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Elias Werberich <elias at werberich dot de>
# Contributor: Struan Robertson <struanrobertson@protonmail.com>

pkgname=grimblast
pkgver=2025.09.22
_commit="de79078fd59140067e53cd00ebdf17f96ce27846" # 2025-09-22
pkgrel=1
pkgdesc="A helper for screenshots within Hyprland."
arch=(any)
url="https://github.com/hyprwm/contrib"
license=(
    MIT
)

makedepends=(
    scdoc
    git
)
source=(
    "$pkgname-$pkgver::git+$url.git#commit=$_commit"
)
b2sums=('131a48b0b0b29535681951c1d977e6720944073bfc058623e499695fcdba4278bf2faad46e03368f1dc43c001c1dfa3d0c786f0e1d84404f8a07e0977dcc592e')

build() {
    cd "$srcdir/$pkgname-$pkgver/$pkgname"
    scdoc < grimblast.1.scd > grimblast.1
}

package() {
    depends+=(
        bash
        grim
        hyprland
        hyprpicker
        jq
        slurp
    )
    cd "$srcdir/$pkgname-$pkgver/$pkgname"

    install -Dm0644 $pkgname.1 "$pkgdir/usr/share/man/man1/$pkgname.1"
    install -Dm0755 $pkgname "$pkgdir/usr/bin/$pkgname"
    install -Dm0644 "$srcdir/$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim: set ft=sh ts=4 sw=4 et: