# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Elias Werberich <elias at werberich dot de>
# Contributor: Struan Robertson <struanrobertson@protonmail.com>

pkgname=grimblast
pkgver=2025.09.30
_commit="513d71d3f42c05d6a38e215382c5a6ce971bd77d" # 2025-09-30
pkgrel=1
pkgdesc="A helper for screenshots within Hyprland."
arch=(any)
url="https://github.com/hyprwm/contrib"
license=(
    MIT
)
makedepends=(
    scdoc
    git
)
source=(
    "${pkgname}-${pkgver}::git+${url}.git#commit=${_commit}"
)
b2sums=('5d2db4e6f7f0de43626e87816ac9f7730a82c1a4304a168116d4a91511853ffc848a0243f19bf7138bbf258c0a18e075bd35745a1febf8735b69b34f6ea209ff')

build() {
    cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"
    scdoc < grimblast.1.scd > grimblast.1
}

package() {
    depends+=(
        bash
        grim
        hyprland
        hyprpicker
        jq
        slurp
    )
    cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"

    install -Dm0644 ${pkgname}.1 "$pkgdir/usr/share/man/man1/${pkgname}.1"
    install -Dm0755 ${pkgname} "$pkgdir/usr/bin/${pkgname}"
    install -Dm0644 "$srcdir/${pkgname}-${pkgver}/LICENSE" \
        "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}

# vim: set ft=sh ts=4 sw=4 et: