# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Elias Werberich <elias at werberich dot de>
# Contributor: Struan Robertson <struanrobertson@protonmail.com>

pkgname=grimblast
pkgver=2025.09.29
_commit="125043bea28e5f988f4e97250213948667a26b1c" # 2025-09-29
pkgrel=1
pkgdesc="A helper for screenshots within Hyprland."
arch=(any)
url="https://github.com/hyprwm/contrib"
license=(
    MIT
)
makedepends=(
    scdoc
    git
)
source=(
    "${pkgname}-${pkgver}::git+${url}.git#commit=${_commit}"
)
b2sums=('7f5c003e0b5335ab1ce04e4a4efda57c6905e152b2775d285ba8a754f759dc11dece627fb08e8712f7331b0d3bf1005e15fe7506a214b5ac27a86b9681f55fc9')

build() {
    cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"
    scdoc < grimblast.1.scd > grimblast.1
}

package() {
    depends+=(
        bash
        grim
        hyprland
        hyprpicker
        jq
        slurp
    )
    cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"

    install -Dm0644 ${pkgname}.1 "$pkgdir/usr/share/man/man1/${pkgname}.1"
    install -Dm0755 ${pkgname} "$pkgdir/usr/bin/${pkgname}"
    install -Dm0644 "$srcdir/${pkgname}-${pkgver}/LICENSE" \
        "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}

# vim: set ft=sh ts=4 sw=4 et: