# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Elias Werberich <elias at werberich dot de>
# Contributor: Struan Robertson <struanrobertson@protonmail.com>

pkgname=grimblast
pkgver=2025.09.15
_commit="9e73a0e753251fbc6e987bd13324886dc6ca8f9a" # 2025-09-15
pkgrel=2
pkgdesc="A helper for screenshots within Hyprland."
arch=(any)
url="https://github.com/hyprwm/contrib"
license=(
    MIT
)

makedepends=(
    scdoc
    git
)
source=(
    "$pkgname-$pkgver::git+$url.git#commit=$_commit"
)
b2sums=('b0a487a0eebc969ebc6b98353a0cec450a52e4bf93423f595b2132a6f59cd66454f5cc7a24e31ef9bf8741310c07370616cb2099fd1e2278be8b851d8a8e5dd2')

build() {
    cd "$srcdir/$pkgname-$pkgver/$pkgname"
    scdoc < grimblast.1.scd > grimblast.1
}

package() {
    depends+=(
        bash
        grim
        hyprland
        hyprpicker
        jq
        slurp
    )
    cd "$srcdir/$pkgname-$pkgver/$pkgname"

    install -Dm0644 $pkgname.1 "$pkgdir/usr/share/man/man1/$pkgname.1"
    install -Dm0755 $pkgname "$pkgdir/usr/bin/$pkgname"
    install -Dm0644 "$srcdir/$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim: set ft=sh ts=4 sw=4 et: