# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Elias Werberich <elias at werberich dot de>
# Contributor: Struan Robertson <struanrobertson@protonmail.com>

pkgname=grimblast
pkgver=2025.10.04
_commit="32e1a75b65553daefb419f0906ce19e04815aa3a" # 2025.10.04
pkgrel=1
pkgdesc="A helper for screenshots within Hyprland."
arch=(any)
url="https://github.com/hyprwm/contrib"
license=(
    MIT
)
makedepends=(
    scdoc
    git
)
source=(
    "${pkgname}-${pkgver}::git+${url}.git#commit=${_commit}"
)
b2sums=('155da0152b70a4f89e539e0f290bbd1fc6a4db147fea40c3b9cf19fa4d7362b9586de3afbda6701ea8098669a57bf6c0fa9b9a12abfa8457ca55ccf43cb5d591')

build() {
    cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"
    scdoc < grimblast.1.scd > grimblast.1
}

package() {
    depends+=(
        bash
        grim
        hyprland
        hyprpicker
        jq
        slurp
    )
    cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"

    install -Dm0644 ${pkgname}.1 "$pkgdir/usr/share/man/man1/${pkgname}.1"
    install -Dm0755 ${pkgname} "$pkgdir/usr/bin/${pkgname}"
    install -Dm0644 "$srcdir/${pkgname}-${pkgver}/LICENSE" \
        "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}

# vim: set ft=sh ts=4 sw=4 et: