Initial commit

PKGBUILD

@@ -0,0 +1,86 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: Mark Wagie <mark dot wagie at proton dot me>
+
+pkgname=hardinfo2
+pkgver=2.2.13
+pkgrel=2
+pkgdesc="System Information and Benchmark for Linux Systems."
+arch=('x86_64' 'aarch64' 'riscv64')
+url="https://github.com/hardinfo2/hardinfo2"
+license=(
+    'GPL-2.0-or-later AND GPL-3.0-or-later AND LGPL-2.1-or-later'
+)
+depends=(
+    bash
+    cairo
+    gcc-libs
+    gdk-pixbuf2
+    glib2
+    glibc
+    glslang
+    gtk3
+    hicolor-icon-theme
+    json-glib
+    libdecor
+    libsoup3
+    libx11
+    libxcb
+    mesa-utils
+    pango
+    vulkan-headers
+    vulkan-icd-loader
+    vulkan-tools
+    wayland
+)
+makedepends=(
+    cmake
+    git
+    qt5-base
+)
+checkdepends=(
+    appstream
+)
+optdepends=(
+    'dmidecode: Memory Devices / System DMI module'
+    'fwupd: Firmware module'
+    'gawk: determine System Type'
+    'iperf3: Internal Network Speed benchmark'
+    'lm_sensors: Sensors module'
+    'pciutils: PCI Devices module'
+    'qt5-base: OpenGL benchmark'
+    'sysbench: SysBench CPU benchmark'
+    'udisks2: Storage module'
+    'usbutils: USB Devices module'
+    'xdg-utils: open your browser for bugs, homepage & links'
+    'xorg-xrandr: read monitor setup'
+) # 'mesa-utils: GLX info for Display module'
+
+provides=('hardinfo')
+conflicts=('hardinfo')
+install="$pkgname.install"
+source=("$pkgname-$pkgver::git+$url.git#tag=release-$pkgver")
+b2sums=('ff04c63ee0da1dfd37a0d6b0284c68df59e12ff245fd189d5a042acad95d68a868f0dde135212fe521b58b5d330a2f0aaa8eefaee99043ca4052875668761005')
+
+build() {
+    local cmake_options=(
+        -B build
+        -S "$pkgname-$pkgver"
+        -DCMAKE_BUILD_TYPE='None'
+        -DCMAKE_INSTALL_PREFIX='/usr'
+        -DCMAKE_INSTALL_LIBDIR='lib'
+        -Wno-dev
+        )
+    cmake "${cmake_options[@]}"
+    cmake --build build
+}
+
+check() {
+    desktop-file-validate "build/$pkgname.desktop"
+    appstreamcli validate --no-net "build/org.$pkgname.$pkgname.metainfo.xml"
+}
+
+package() {
+    DESTDIR="$pkgdir" cmake --install build
+}
+
+# vim: set ft=sh ts=4 sw=4 et: