Initial commit

PKGBUILD

@@ -0,0 +1,47 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# OriginalMaintainer (aur): Filip Markovic <f12markovic at gmail dot com>
+pkgname="hyprevents-git"
+pkgver=r24.d4397df
+pkgrel=2
+arch=(any)
+pkgdesc="Invoke shell functions in response to Hyprland socket2 events"
+url="https://github.com/vilari-mickopf/hyprevents"
+license=(
+    MIT
+)
+depends=(
+    bash
+)
+makedepends=(
+    git
+)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("${pkgname%-git}::git+${url}.git")
+md5sums=('SKIP')
+
+pkgver() {
+    cd "$srcdir"/"${pkgname%-git}"
+    (
+      set -o pipefail
+      git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+          printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+    )
+}
+
+package() {
+    cd "$srcdir/${pkgname%-git}"
+    make \
+        PREFIX="$pkgdir/usr" \
+        install
+
+    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-git}" "README.md"
+    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" "LICENSE"
+    cd "$pkgdir/usr/share/hyprevents"
+    sed -i 's|^EVENT_HANDLER=.*|EVENT_HANDLER="/usr/share/hyprevents/event_handler"|' event_loader
+
+    cd "$pkgdir/usr/bin"
+    sed -i 's|^EVENT_LOADER=.*|EVENT_LOADER="/usr/share/hyprevents/event_loader"|' hyprevents
+}
+
+# vim: set ft=sh ts=4 sw=4 et: