Initial commit

PKGBUILD

@@ -0,0 +1,49 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: Filip Markovic <f12markovic at gmail dot com>
+pkgname="hyprprop-git"
+pkgver=r23.f106bbd
+pkgrel=2
+pkgdesc="xprop for Hyprland"
+url="https://github.com/vilari-mickopf/hyprprop"
+arch=(any)
+license=(
+    MIT
+)
+depends=(
+    bash
+    hyprevents-git
+    socat
+    slurp
+    jq
+)
+makedepends=(
+    git
+)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("${pkgname%-git}::git+${url}.git")
+md5sums=('SKIP')
+
+pkgver() {
+    cd "$srcdir"/"${pkgname%-git}"
+    (
+        set -o pipefail
+        git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+            printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+    )
+}
+
+package() {
+    cd "$srcdir/${pkgname%-git}"
+    make \
+        PREFIX="$pkgdir/usr" \
+        install
+
+    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-git}" "README.md"
+    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" "LICENSE"
+
+    cd "$pkgdir/usr/bin"
+    sed -i 's|^EVENT_HANDLER=.*|EVENT_HANDLER="/usr/share/hyprprop/event_handler"|' hyprprop
+}
+
+# vim: set ft=sh ts=4 sw=4 et: