# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Filip Markovic <f12markovic at gmail dot com>
pkgname="hyprprop"
pkgver=20251209.141110
_commit=80de2f89ba0e66fad406a5834d367632d5922609
pkgrel=1
pkgdesc="xprop for Hyprland"
url="https://github.com/vilari-mickopf/hyprprop"
arch=(any)
license=(
    MIT
)
depends=(
    bash
    hyprevents-git
    socat
    slurp
    jq
)
makedepends=(
    git
)
provides=("${pkgname}")
conflicts=("${pkgname}-git")
source=("${pkgname}-${pkgver}::git+${url}.git#commit=${_commit}")
b2sums=('337fdab516646dc0ebd95e4c075a5ccc58dbef83ae53c3fb7a0d70168b6380b5ae638bd197d2b1d2391c0013d9d7b365e167bb76082c519d36be90ab501711cc')

package() {
    cd "${pkgname}-${pkgver}"
    make \
        PREFIX="$pkgdir/usr" \
        install

    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-git}" "README.md"
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" "LICENSE"

    cd "$pkgdir/usr/bin"
    sed -i 's|^EVENT_HANDLER=.*|EVENT_HANDLER="/usr/share/hyprprop/event_handler"|' hyprprop
}

# vim: set ft=sh ts=4 sw=4 et: