# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Filip Markovic <f12markovic at gmail dot com>
pkgname="hyprprop"
pkgver=20251020.215441
_commit=5952f28b2f734122e8e39de5c08e89420f2501b0
pkgrel=1
pkgdesc="xprop for Hyprland"
url="https://github.com/vilari-mickopf/hyprprop"
arch=(any)
license=(
    MIT
)
depends=(
    bash
    hyprevents-git
    socat
    slurp
    jq
)
makedepends=(
    git
)
provides=("${pkgname}")
conflicts=("${pkgname}-git")
source=("${pkgname}-${pkgver}::git+${url}.git#commit=${_commit}")
b2sums=('3a7c69183b69673678c18ee337dd4dbf8e88d6269381ee2f71812864b1345251426e2c81cc8d0851b0f9c65364edbb989f7aa3ab418c00fa8e60db1d309ee424')

package() {
    cd "${pkgname}-${pkgver}"
    make \
        PREFIX="$pkgdir/usr" \
        install

    install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-git}" "README.md"
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" "LICENSE"

    cd "$pkgdir/usr/bin"
    sed -i 's|^EVENT_HANDLER=.*|EVENT_HANDLER="/usr/share/hyprprop/event_handler"|' hyprprop
}

# vim: set ft=sh ts=4 sw=4 et: