Initial commit

PKGBUILD

@@ -0,0 +1,59 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: alba4k <blaskoazzolaaaron@gmail.com>
+
+pkgname="hyprsysteminfo"
+pkgver=0.1.3
+pkgrel=10
+pkgdesc="A tiny qt6/qml application to display information about the running system"
+arch=(
+    x86_64
+    aarch64
+)
+url="https://github.com/hyprwm/hyprsysteminfo"
+license=(
+    BSD-3-Clause
+)
+depends=(
+    gcc-libs
+    glibc
+    hyprutils libhyprutils.so
+    hyprland-qt-support
+    qt6-base
+    qt6-declarative
+    qt6-wayland
+)
+makedepends=(
+    cmake
+    gcc
+    git
+    vulkan-headers
+)
+source=(
+    "$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
+)
+b2sums=('eb8223dba0e414acf54d2fa6a4f5606ae8037ea1c8ea811bc703a3f1ad7a8e6e4ca8e8c2c2d20bd8650a1ee4f3dab4b7fae1d5da45e4c01dc426e41f3a485e8e')
+provides=("hyprsysteminfo")
+conflicts=("${pkgname}-git")
+
+build() {
+    local cmake_options=(
+        -S "$pkgname-$pkgver"
+        -B build
+        --no-warn-unused-cli
+        -D CMAKE_BUILD_TYPE=Release
+        -DCMAKE_INSTALL_PREFIX=/usr
+    )
+    cmake "${cmake_options[@]}"
+    cmake \
+        --build build \
+        --config Release \
+        --target hyprsysteminfo
+}
+
+package() {
+    DESTDIR="$pkgdir" cmake --install build
+    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" "$pkgname-$pkgver/README.md"
+    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgname-$pkgver/LICENSE"
+}
+
+# vim: set ft=sh ts=4 sw=4 et: