# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Matt Harrison <matt@harrison.us.com>

pkgname=iwqt
pkgver=0.0.3
pkgrel=3
pkgdesc="An iwd network applet for linux systems"
url="https://github.com/FinGu/iwqt"
arch=(
    x86_64
)
license=(
    GPL-3.0-only
)
depends=(
    gcc-libs
    glibc
    iwd
    qt6-base
    sdbus-cpp
    qt6-svg
)
makedepends=(
    cmake
    git
    meson
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
    "ca107568-2808-4d5a-99be-7fde89b411d7.patch"
    "icons.patch"
)
b2sums=('ea6063113d2e456f14a3dc11d059d1727e14ac0f2b4a63e78d7e9cd4e75df640babbd86c59ebce1d8983111b0e0ad617c382319c91f37a13c2677852e8fda03a'
        '4f843f7c63bef50aff80274649197290441b42d67425de1db54a53f469eaf6f7941becdb1a2fd33b5b1814bb99ed2ad82c5b47b17f6a377a1101ed6ad2b369a2'
        'cd7b7a383d39fd57a74a56e4a10d4b99a3504a0be09114e6cd611c4ad044ef845fe3f644ccb5cabf81368f0f27cc3a2686b212dcec45144dc4316a651688762c')

prepare() {
    cd "${pkgname}-${pkgver}"
    patch -Np1 -i ../icons.patch
    patch -Np1 -i ../ca107568-2808-4d5a-99be-7fde89b411d7.patch
    # Currently no subprojects but leaving this here for conisistancy.
    meson subprojects download --sourcedir=.
}


build() {
    arch-meson "$pkgname-$pkgver" build
    meson compile -C build
}

# no tests currently
# check() {
#   cd "${srcdir}/${pkgname}-${pkgver}"
#   meson test -C build
# }

package() {
  meson install -C build --destdir "$pkgdir"
  install -Dm0644 "${pkgname}-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}