# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Andrew Rabert <ar@nullsum.net>

pkgname=jellyfin-desktop
pkgver=2.0.0
pkgrel=1
pkgdesc='Jellyfin Desktop Client'
arch=('i686' 'x86_64')
license=(
    GPL-2.0-only
)
url='https://github.com/jellyfin/jellyfin-desktop'
depends=(
    libcec
    gcc-libs
    glibc
    hicolor-icon-theme
    mpv
    mpvqt
    p8-platform
    protobuf
    qt6-base
    qt6-webchannel
    qt6-declarative
    qt6-webengine
    sdl2
    libxrandr
    libx11
    minizip
)
makedepends=(
    cmake
    git
    ninja
    python
)
replaces=(
    jellyfin-media-player
)
source=("$pkgname-$pkgver::git+$url.git#tag=v$pkgver")
b2sums=('fafd83385b8bde2579eb92935aea6a827365efffe71ddac9bb6740a4a507157bb46637060893fa108f21136c6e4966d23e11bc1929c9b935ee052aa366ec90c2')


build() {
    local cmake_options=(
        -S "$pkgname-$pkgver"
        -B build
        -D CMAKE_BUILD_TYPE=None
        -D CMAKE_INSTALL_PREFIX=/usr
        -D CMAKE_SKIP_RPATH=1
        -D CHECK_FOR_UPDATES=OFF
        -D QTROOT=build/qt
        -G Ninja
        -W no-dev
    )
    cmake "${cmake_options[@]}"
    cmake --build build
}

package() {
    DESTDIR="${pkgdir}" cmake --install build
}

# vim: set ft=sh ts=4 sw=4 et: