# Maintainer: Kelvie Wong <kelvie@kelvie.ca>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Kuba Serafinowski <zizzfizzix(at)gmail(dot)com>

_pkgname=kdeconnect
pkgname=kdeconnect-no-mdns
provides=("${_pkgname}")
conflicts=("${_pkgname}")
pkgver=25.08.3
pkgrel=1
epoch=1
pkgdesc="Adds communication between KDE and your smartphone. Version without MDNS support, for KDE bug 487719."
url="https://kdeconnect.kde.org/"
_sourceurl="https://download.kde.org/stable/release-service"
arch=(x86_64)
license=(GPL-2.0-or-later)
depends=(
    dbus
    gcc-libs
    glib2
    glibc
    hicolor-icon-theme
    kconfig
    kcoreaddons
    kcrash
    kdbusaddons
    kdeclarative
    kguiaddons
    ki18n
    kiconthemes
    kio
    kirigami
    kirigami-addons
    kitemmodels
    kjobwidgets
    knotifications
    kpeople
    kservice
    kstatusnotifieritem
    kwindowsystem
    libfakekey
    libplasma
    libx11
    libxkbcommon
    libxtst
    modemmanager-qt
    openssl
    pulseaudio-qt
    python
    python-gobject
    qqc2-desktop-style
    qt6-base
    qt6-connectivity
    qt6-declarative
    qt6-multimedia
    solid
    wayland
)
makedepends=(
    extra-cmake-modules
    git
    kpackage # kpackage_install_package
    vulkan-headers
    wayland-protocols
)
optdepends=(
    'python-nautilus: Nautilus integration'
    'qt6-tools: for some runcommand plugin actions'
    'sshfs: remote filesystem browser'
)
source=(
    "${_sourceurl}/${pkgver}/src/${_pkgname}-kde-${pkgver}.tar.xz"
    "${_sourceurl}/${pkgver}/src/${_pkgname}-kde-${pkgver}.tar.xz.sig"
)
b2sums=('8ca67bcc7cc3407ff8380c9ef5f1778e19b8135995d30f93143103b95715d3966e21e48196d19dc5a59bda5d8883f6f045c1b8ad9433850ea54a4855748fef30'
        'SKIP')
validpgpkeys=(
    CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
    F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
    D81C0CB38EB725EF6691C385BB463350D6EF31EF  # Heiko Becker <heiko.becker@kde.org>
)


build() {
    local cmake_options=(
        -S "${_pkgname}-kde-${pkgver}"
        -B build
        -D BUILD_TESTING=OFF
        -D MDNS_ENABLED=OFF
    )
    cmake "${cmake_options[@]}"
    cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
}