Initial commit

PKGBUILD

@@ -0,0 +1,63 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: Nico <d3sox at protonmail dot com>
+
+pkgname=kwin-effects-forceblur
+pkgver=1.5.0
+pkgrel=3
+pkgdesc="KWin Blur effect fork with window class force blur feature (Wayland & X11)"
+arch=(
+    x86_64
+)
+url="https://github.com/taj-ny/kwin-effects-forceblur"
+license=(
+    GPL-3.0-or-later
+)
+depends=(
+    gcc-libs
+    glibc
+    kcmutils
+    kcrash
+    kdecoration
+    kglobalaccel
+    ki18n
+    kio
+    kconfig
+    kcoreaddons
+    knotifications
+    kwidgetsaddons
+    kwin
+    libepoxy libepoxy.so
+    qt6-base
+)
+makedepends=(
+    appstream
+    extra-cmake-modules
+    git
+    qt6-tools
+    vulkan-headers
+)
+provides=(kwin-effects-better-blur)
+source=(
+    "$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
+    "$pkgname.install")
+install="$pkgname.install"
+b2sums=('ccce168b60300b0480f02fed094a74f761fc7ad49062c3a4bf30c8bbfa14c5b83b41495fbd7d9669ff771c2c7d981a993dc988cd3791ef4586288eb25fa28c98'
+        '5de5efda9bdc11103a6b5ada6fd1f5907920cb55bd129bc3bcc55f9424d5703031a7a6696fa20ffabe456bd66881ccfa93d804c4b88ed9d7ca2f3f8d6c5005a7')
+
+build() {
+    local cmake_options=(
+        -B build
+        -S "$pkgname-$pkgver"
+        -DCMAKE_BUILD_TYPE='None'
+        -DCMAKE_INSTALL_PREFIX='/usr'
+        )
+    cmake "${cmake_options[@]}"
+    cmake --build build
+}
+
+package() {
+    DESTDIR="$pkgdir" cmake --install build
+    install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" "$pkgname-$pkgver"/*.md
+}
+
+# vim: set ft=sh ts=4 sw=4 et: