# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Mahdi Sarikhani <mahdisarikhani@outlook.com>
# Contributor: Martin Rys <https://rys.rs/contact>
# Contributor: Malte Jürgens <maltejur@dismail.de>

pkgname=libation
pkgver=12.5.6
pkgrel=1
pkgdesc="Audible audiobook manager: liberate your Library"
arch=(
    x86_64
)
url="https://github.com/rmcrackan/Libation"
license=(
    GPL-3.0-only
)
depends=(
    bash
    fontconfig
    gcc-libs
    glibc
    hicolor-icon-theme
    lttng-ust2.12
)
makedepends=(
    'dotnet-sdk>=9'
    git
)
source=(
    "${pkgname^}-${pkgver}::git+$url.git#tag=v$pkgver"
)
b2sums=('5cf06a01e4a03768c0f8bdabbeb5aefd10936afc922a7a5e7a20ed63d6301ebaa0981cef30eb3683424aadcd5fbbf67d85083e4367be0fc777cc495fc978966f')

build() {
    cd "${pkgname^}-${pkgver}"
    local dotnet_options=(
        --configuration Release
        --output build
        --runtime linux-x64
    )
    dotnet publish Source/LibationAvalonia/LibationAvalonia.csproj \
        "${dotnet_options[@]}" \
        -p:PublishProfile=Source/LibationAvalonia/Properties/PublishProfiles/LinuxProfile.pubxml
    dotnet publish Source/LoadByOS/LinuxConfigApp/LinuxConfigApp.csproj \
        "${dotnet_options[@]}" \
        -p:PublishProfile=Source/LoadByOS/LinuxConfigApp/Properties/PublishProfiles/LinuxProfile.pubxml
    dotnet publish Source/LibationCli/LibationCli.csproj \
        "${dotnet_options[@]}" \
        -p:PublishProfile=Source/LibationCli/Properties/PublishProfiles/LinuxProfile.pubxml
    dotnet publish Source/HangoverAvalonia/HangoverAvalonia.csproj \
        "${dotnet_options[@]}" \
        -p:PublishProfile=Source/HangoverAvalonia/Properties/PublishProfiles/LinuxProfile.pubxml
}

package() {
    cd "${pkgname^}-${pkgver}"
    install -Dm0755 build/* -t "${pkgdir}/usr/lib/${pkgname}"
    install -Dm0644 Source/LoadByOS/LinuxConfigApp/Libation.desktop \
        "${pkgdir}/usr/share/applications/${pkgname}.desktop"
    install -Dm0644 Images/libation_glass.svg \
        "${pkgdir}/usr/share/icons/hicolor/scalable/apps/${pkgname}.svg"

    install -d "${pkgdir}/usr/bin"
    ln -s "/usr/lib/${pkgname}/Libation" "${pkgdir}/usr/bin/libation"
    ln -s "/usr/lib/${pkgname}/Hangover" "${pkgdir}/usr/bin/hangover"
    ln -s "/usr/lib/${pkgname}/LibationCli" "${pkgdir}/usr/bin/libationcli"
}