# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Zeph <zeph33@gmail.com>
# https://gitlab.manjaro.org/packages/extra/libpamac
ENABLE_FLATPAK=1
ENABLE_SNAPD=0

pkgname=libpamac-aur
pkgver=11.7.4
pkgrel=2
epoch=1
_pkgfixver=$pkgver

_commit='b260c6c28b076375ae80656072cd9bd74f0f6d63'
sha256sums=('09291690324f8c50ea909dbb2a1895e7a330cd572d55dde2fd2a5a00954086fa'
            '6e0c25f0fcb0076ce78845b037e32925fcc3f1cd1670062c48ed35f564a10244'
            'b5236af02c25cd7de4b2c9c2d0f064dac3c2f54da5cc72bf72fc6236a34bd9c4'
            '3fcfd42d789d1e669c722ed7314fa41686a0a88f947d77755c43bc12439e119f')

pkgdesc="Pamac package manager library based on libalpm"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/manjaro/libpamac/"
license=('GPL-3.0-or-later')
depends=('glib2>=2.42' 'json-glib' 'libsoup3' 'dbus-glib' 'polkit' 'vte3>=0.38' 'libalpm.so=16-64'
         'libnotify' 'pacman>=7.0' 'gnutls>=3.4' 'appstream'
         'appstream-glib>=0.7.18-1' 'archlinux-appstream-data' 'git')

makedepends=('gettext' 'itstool' 'vala>=0.46'  'asciidoc' 'meson' 'ninja' 'gobject-introspection' 'systemd')
backup=('etc/pamac.conf')
conflicts=('libpamac' 'libpamac-all')
provides=('libpamac.so=11' 'libpamac-appstream.so=11' "libpamac=$_pkgfixver")
options=(!emptydirs !strip)
install=pamac.install
source=(
    "libpamac-$pkgver-$pkgrel.zip::$url/archive/$_commit.zip"
    'fix-appstream-data.sh'
    'fix-appstream-data.hook'
    "support_libalpm-16.patch::https://github.com/manjaro/libpamac/commit/add94a888180ddbe04acae082e9db5cfb34c2fcd.patch"
)

define_meson=''
if [ "${ENABLE_FLATPAK}" = 1 ]; then
  depends+=('flatpak')
  define_meson+=' -Denable-flatpak=true'
fi

if [ "${ENABLE_SNAPD}" = 1 ]; then
  depends+=('snapd' 'snapd-glib')
  define_meson+=' -Denable-snap=true'
fi

create_links() {
  # create soname links
  find "$pkgdir" -type f -name '*.so*' ! -path '*xorg/*' -print0 | while read -d $'\0' _lib; do
      _soname=$(dirname "${_lib}")/$(readelf -d "${_lib}" | grep -Po 'SONAME.*: \[\K[^]]*' || true)
      _base=$(echo ${_soname} | sed -r 's/(.*)\.so.*/\1.so/')
      [[ -e "${_soname}" ]] || ln -s $(basename "${_lib}") "${_soname}"
      [[ -e "${_base}" ]] || ln -s $(basename "${_soname}") "${_base}"
  done
}

prepare() {
  patch -d "$srcdir/libpamac-$_commit" -Np1 -i ../support_libalpm-16.patch
  cd "$srcdir/libpamac-$_commit"
  # adjust version string
  sed -i -e "s|\"$_pkgfixver\"|\"$pkgver-$pkgrel\"|g" src/version.vala
}

build() {
  cd "$srcdir/libpamac-$_commit"
  arch-meson build -Denable-aur=true -Denable-appstream=true $define_meson
  # build
  meson compile -C build
}

package() {
  cd "$srcdir/libpamac-$_commit"
  meson install -C build --no-rebuild --destdir "$pkgdir"
  # fix appstream issue
  install -Dm644 "$srcdir/fix-appstream-data.hook" "$pkgdir/etc/pacman.d/hooks/fix-appstream-data.hook"
  install -Dm755 "$srcdir/fix-appstream-data.sh" "$pkgdir/etc/pacman.d/hooks.bin/fix-appstream-data.sh"
  create_links

}

# vim: set ft=sh ts=4 sw=4 et: