Initial commit

PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+
+pkgname=menulibre
+pkgver=2.4.0
+pkgrel=3
+pkgdesc="An advanced menu editor that provides modern features in a clean, easy-to-use interface"
+arch=(any)
+url="https://github.com/bluesabre/$pkgname"
+license=(
+    GPL-3.0-or-later
+)
+depends=(
+    gdk-pixbuf2
+    glib2
+    gnome-menus
+    gsettings-desktop-schemas
+    gtk3
+    gtksourceview3
+    hicolor-icon-theme
+    pango
+    python
+    python-gobject
+    python-psutil
+    python-xdg
+    xdg-utils
+)
+makedepends=(
+    git
+    python-distutils-extra
+)
+install=$pkgname.install
+source=("$pkgname-$pkgver::git+$url.git#tag=$pkgname-${pkgver}?signed")
+b2sums=('a8ddc7357f8b701338da58e2a5fc524b69142775cfa4efdcedfcf19a1ba3fef1cb93fcc4ce24001e8b54a7a8588210d176bd60b4270c505279465fda0bf13e25')
+validpgpkeys=(
+    'F93865C8045D54A864477AF0B72F4B093A3625DB' # Sean Davis <sean@bluesabre.org>
+)
+
+package() {
+    cd "$pkgname-$pkgver"
+    python setup.py install --root="$pkgdir/" --optimize=1
+    install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" AUTHORS
+    install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" NEWS README.md
+}
+
+# vim: set ft=sh ts=4 sw=4 et: