# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: begin-theadventure <begin-thecontact.ncncb at dralias dot com>
pkgname=mousam
pkgver=1.4.0
pkgrel=2
pkgdesc="Weather at a Glance"
arch=(any)
url="https://github.com/amit9838/mousam"
license=(
    GPL-3.0-or-later
)
depends=(
    dconf
    gdk-pixbuf2
    glib2
    gtk4
    hicolor-icon-theme
    libadwaita
    python
    python-cairo
    python-gobject
    python-requests
)
checkdepends=(
    appstream-glib
)
makedepends=(
    git
    meson
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
    'hotfix.patch'
)
b2sums=('ac6226ca955ed74ea7506ac48c353763551bd207f6a4e7d4957b1b14f384a70683364abeb5d60a99bda508219942299c51998d52677f53b5c478d9677e6caf96'
        '6841dd7e7b738feb7fbb6e1006466bc1caf278e8a982e7effc3010a4dab91c6ffdc0e0cfc196682e3d75ec2ea9e809e9aecfd2a5695b13c03ea97b65cc58fa02')

prepare() {
    cd "$pkgname-$pkgver"
patch -p1 -i ../hotfix.patch
}

build() {
    arch-meson $pkgname-$pkgver build
    meson compile -C build
}

check() {
    meson test -C build --print-errorlogs || :
}

package() {
    meson install -C build --destdir "$pkgdir"
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" \
        $pkgname-$pkgver/CODE_OF_CONDUCT.md \
        $pkgname-$pkgver/CONTRIBUTION_GUIDE.md \
        $pkgname-$pkgver/README.md
}

# vim: set ft=sh ts=4 sw=4 et: