# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: begin-theadventure <begin-thecontact.ncncb at dralias dot com>
pkgname=mousam
pkgver=1.4.0
pkgrel=3
pkgdesc="Weather at a Glance"
arch=(any)
url="https://github.com/amit9838/mousam"
license=(
    GPL-3.0-or-later
)
depends=(
    dconf
    gdk-pixbuf2
    glib2
    gtk4
    hicolor-icon-theme
    libadwaita
    python
    python-cairo
    python-gobject
    python-requests
)
checkdepends=(
    appstream-glib
)
makedepends=(
    git
    meson
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
    'hotfix.patch'
)
b2sums=('ac6226ca955ed74ea7506ac48c353763551bd207f6a4e7d4957b1b14f384a70683364abeb5d60a99bda508219942299c51998d52677f53b5c478d9677e6caf96'
        '7d2da7eb660e948dc5a151f9c1d2008937a07f398bb9c1829a181c79d056e793d7500956702a0667fe64de61234b09e23749be4dfbc0f242eb0cca2bfc4f86f6')

prepare() {
    cd "$pkgname-$pkgver"
patch -p1 -i ../hotfix.patch
}

build() {
    arch-meson $pkgname-$pkgver build
    meson compile -C build
}

check() {
    meson test -C build --print-errorlogs || :
}

package() {
    meson install -C build --destdir "$pkgdir"
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" \
        $pkgname-$pkgver/CODE_OF_CONDUCT.md \
        $pkgname-$pkgver/CONTRIBUTION_GUIDE.md \
        $pkgname-$pkgver/README.md
}

# vim: set ft=sh ts=4 sw=4 et: