# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor:   Ataberk Özen <ataberkozen123@gmail.com>
# Contributor:  Bruno Nova <brunomb.nova@gmail.com>

pkgname=nautilus-admin-gtk4
pkgver=1.2.0
pkgrel=2
pkgdesc="Extension for Nautilus to do administrative operations"
arch=(
    any
)
url="https://github.com/MacTavishAO/$pkgname"
license=(GPL-3.0-or-later)
depends=(
    glib2
    libnautilus-extension
    nautilus
    polkit
    python
    python-gobject
    python-nautilus
)
makedepends=(
    'cmake>=2.6'
    gettext
    git
)
optdepends=(
    'gedit: to use the "Edit as Administrator" action'
    'gnome-terminal: to use the "Run as Administrator" action'
)
install="$pkgname.install"
source=("$pkgname-$pkgver::git+$url.git#tag=$pkgver")
b2sums=('19fd07390fbb7701c78f43c20e10f5dc2879b343fdc01e3cdb35097acfbb3d2ae1e79e83a6d12a05768f4c5ea7a2ec4ae416901ac6ca0be6497e149f1b937695')

build() {
    cd "$pkgname-$pkgver"
    cmake . \
        -DCMAKE_INSTALL_PREFIX=/usr
    make
}

package() {
    cd "$pkgname-$pkgver"
    make \
        DESTDIR="$pkgdir" \
        install
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/README.md" README.md NEWS AUTHORS
}

# vim: set ft=sh ts=4 sw=4 et: