# Maintainer: Łukasz Moroz <lukaszmoroz@gmail.com>

pkgname=nautilus-copy-path
pkgver=1.10.2
pkgrel=2
pkgdesc="Configurable extension for Nautilus to copy path, URI, or name"
arch=('any')
url="https://github.com/chr314/$pkgname"
license=(
    MIT
)
depends=(
    glib2
    libnautilus-extension
    python
    python-gobject
    python-nautilus
)
makedepends=(
    git
)
backup=("usr/share/nautilus-python/extensions/$pkgname/config.json")
install=$pkgname.install
source=(
    "$pkgname-$pkgver::git+$url.git#tag=$pkgver"
    'fix_error_with_gi.patch'
)
b2sums=('5f61d7f747b3cb5508b21111c4152d70ac0e68d00df97753209ba782d4d804a9c5b606c6017cbcd132e6b407305d2a5d3b4c71dd76bab15f2d246e198535542c'
        '3711400cd23775a813e1bb24a85610887b981c91106e71ac3d990b76e4f0b9226f63eaee61e3072ce968460c70d90329a998e9b1e6dfee20e88cb42030b27cbc')

prepare() {
    cd "$pkgname-$pkgver"
    patch -p1 -i ../fix_error_with_gi.patch
}

package() {
    cd "$pkgname-$pkgver"
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
    install -Dm0644 -t "$pkgdir/usr/share/nautilus-python/extensions" nautilus-copy-path.py
    install -Dm0644 -t "$pkgdir/usr/share/nautilus-python/extensions/$pkgname" nautilus_copy_path.py config.json translation.py
    install -Dm0644 -t "$pkgdir/usr/share/nautilus-python/extensions/$pkgname/translations" translations/*.json
}

# vim: set ft=sh ts=4 sw=4 et: