Initial commit

PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: Felix Bühler <account at buehler dot de>
+# Contributor: lvxnull <lvxnull at proton dot me>
+
+pkgname=nautilus-open-any-terminal
+pkgver=0.6.1
+pkgrel=2
+pkgdesc="context-menu entry for opening other terminal in nautilus"
+arch=(any)
+url="https://github.com/Stunkymonkey/nautilus-open-any-terminal"
+license=(
+    GPL-3.0-or-later
+)
+depends=(
+    dconf
+    glib2
+    libnautilus-extension
+    python
+    python-gobject
+    python-nautilus
+)
+makedepends=(
+    gettext
+    git
+    make
+)
+source=("$pkgname-$pkgver::git+$url.git#tag=$pkgver")
+b2sums=('be2aa333448604af4c3f11c96ac54a986e63972168e4d83354df3b7aeb23185cf89f4f0fca2aab5cc12dcc1f53e9a62d2274f40bb674b66b77b654d0aad63572')
+
+build() {
+    cd "$pkgname-$pkgver"
+    make build
+}
+
+package() {
+    cd "$pkgname-$pkgver"
+    make PREFIX="${pkgdir}/usr" install-nautilus
+
+    install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" \
+        README.md \
+        screenshot.png
+}
+
+# vim: set ft=sh ts=4 sw=4 et: