# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Felix Bühler <account at buehler dot de>
# Contributor: lvxnull <lvxnull at proton dot me>

pkgname=nautilus-open-any-terminal
pkgver=0.6.3
pkgrel=1
pkgdesc="context-menu entry for opening other terminal in nautilus"
arch=(any)
url="https://github.com/Stunkymonkey/nautilus-open-any-terminal"
license=(
    GPL-3.0-or-later
)
depends=(
    dconf
    glib2
    gtk4
    libnautilus-extension
    python
    python-gobject
    python-nautilus
)
makedepends=(
    gettext
    git
    make
)
source=("$pkgname-$pkgver::git+$url.git#tag=$pkgver")
b2sums=('6585e2dc7abbd35f8f678b9dfec57d1a3345ff1d7d0f7c4ca31741ef80455cd525061b74cbff56c15bcc174d7e6b876b5846865e2dec01451bd60e14641dc8b3')

build() {
    cd "$pkgname-$pkgver"
    make build
}

package() {
    cd "$pkgname-$pkgver"
    make PREFIX="${pkgdir}/usr" install-nautilus

    install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" \
        README.md \
        screenshot.png
}

# vim: set ft=sh ts=4 sw=4 et: