Initial commit

PKGBUILD

@@ -0,0 +1,61 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: Thomas Weißschuh <aur t-8ch de>
+
+pkgname=needrestart
+pkgver=3.11
+pkgrel=2
+arch=(any)
+pkgdesc="Restart daemons after library updates"
+url="https://github.com/liske/needrestart"
+license=(
+    'GPL-2.0-or-later'
+)
+depends=(
+    bash
+    perl
+    perl-module-find
+    perl-term-readkey
+    perl-proc-processtable
+    perl-sort-naturally
+    perl-module-scandeps
+    perl-libintl-perl
+)
+makedepends=(
+    git
+)
+optdepends=(
+    'iucode-tool: for outdated microcode detection'
+)
+options=(
+    !emptydirs
+)
+source=("$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
+        "needrestart.hook")
+b2sums=('c8556a9ecfa8d822d122364d222082c732c8d0b39ce1da3fb1c4698b86746b56556097848e79b26a9dbdad42b8c52bfbfc4fc771b79f0653129b6121ea667994'
+        'f437710081109c2d1dc7fcffebd7e953a31e3be94322f3727eefa8ac2ab6917c9adca90be158a7a1d9df9fa520cd10d633664d427950832b9f76d364b8bfd8d5')
+
+prepare() {
+    cd "$pkgname-$pkgver"
+    sed -i -e 's|/usr/sbin|/usr/bin|' Makefile
+}
+
+build() {
+    cd "$pkgname-$pkgver"
+    unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+    export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+    make
+}
+
+package() {
+    cd "$pkgname-$pkgver"
+    unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+    export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+    make DESTDIR="${pkgdir}" install
+
+    install -Dm444 "${srcdir}/needrestart.hook" \
+        "${pkgdir}/usr/share/libalpm/hooks/needrestart.hook"
+
+    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" NEWS README.*
+}
+
+# vim: set ft=sh ts=4 sw=4 et: