# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Maintainer: Zeph <zeph33@gmail.com>
# https://gitlab.manjaro.org/packages/extra/pamac
ENABLE_FAKE_GNOME_SOFTWARE=0

pkgname=pamac-aur
pkgver=11.7.3
pkgrel=5
_pkgfixver=$pkgver
_pkgfixvercli=11.7.3
_pkgrelcli=1

_commit='06c846c0310030ee45870b190359553b1c105f77'
_commitcli='27cc40525a5820177a9d77028d9e481a500d61ee'
b2sums=('f33f15b0b30ff2695f3bed4d3d66487ea47c4fd8ddb638d43a261941d29d8beb4d1f26a03d3c1b755e133befd26784e03ed0cbc16b9bc2deb1a359e34f4cbc38'
        '391cf70e6f920411ea02f1f21e57192d2883414116a95dcdb38089c7d29ffaf5e0123de947fcc048517d0085d9484fcfc8b8951fc05e0c72ba61fd0ff61f6ff1')

pkgdesc="A Gtk frontend, Package Manager based on libalpm with AUR and Appstream support"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/manjaro/pamac"
urlcli="https://github.com/manjaro/pamac-cli"
license=('GPL-3.0-or-later')
depends=(
    libnotify
    libhandy
    libadwaita
    gdk-pixbuf2
    glib2
    glibc
    gtk3
    gtk4
    hicolor-icon-theme
    'libpamac-aur>=11.7'
    'gnutls>=3.4'
    git
)
optdepends=(
    'polkit-gnome: needed for authentification in Cinnamon, Gnome'
    'lxsession: needed for authentification in Xfce, LXDE etc.'
)
makedepends=(
    gettext
    itstool
    vala
    meson
    ninja
    gobject-introspection
    xorgproto
    asciidoc
    git
    systemd
)
conflicts=(
    pamac
    pamac-tray-appindicator
    pamac-cli
)
provides=(
    "pamac=$_pkgfixver-$pkgrel"
    "pamac-cli=$_pkgfixvercli-$_pkgrelcli"
)
options=(!emptydirs !strip)
install=pamac.install
source=("pamac-$_pkgfixver-$pkgrel.zip::$url/archive/$_commit.zip"
        "pamac-cli-$_pkgfixvercli-$_pkgrelcli.zip::$urlcli/archive/$_commitcli.zip")

define_meson=''
if [ "${ENABLE_FAKE_GNOME_SOFTWARE}" = 1 ]; then
  conflicts+=('pamac-gnome-integration' 'pamac-gnome-integration-dev' 'gnome-software')
  define_meson+=' -Denable-fake-gnome-software=true'
fi

_srcdir="pamac-$_commit"
_srcdircli="pamac-cli-$_commitcli"

prepare() {
  cd "${srcdir}/${_srcdir}"
  # adjust version string
  sed -i -e "s|\"$_pkgfixver\"|\"$pkgver-$pkgrel\"|g" src/version.vala
  cd "${srcdir}/${_srcdircli}"
  # adjust version string
  sed -i -e "s|\"$_pkgfixvercli\"|\"$_pkgfixvercli-$__pkgrelcli\"|g" src/version.vala
}

build() {
  cd "${srcdir}/${_srcdir}"
  mkdir -p builddir && cd builddir
  meson --buildtype=release \
        --prefix=/usr \
        --sysconfdir=/etc $define_meson
  ninja

  cd "${srcdir}/${_srcdircli}"
  mkdir -p builddir && cd builddir
  meson setup --prefix=/usr --sysconfdir=/etc --buildtype=release
	meson compile
}

package() {
  cd "${srcdir}/${_srcdir}/builddir"
  DESTDIR="$pkgdir" ninja install
  cp -r "$srcdir/pamac-$_commit/data/gnome-shell/pamac-updates@manjaro.org" "$pkgdir/usr/share/gnome-shell/extensions"
  cd "${srcdir}/${_srcdircli}/builddir"
  meson install --destdir "$pkgdir"

  install -Dm644 "${srcdir}/${_srcdir}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim: set ft=sh ts=4 sw=4 et: